home *** CD-ROM | disk | FTP | other *** search
/ Wonky Flux Batch 2019 02 / Wonky_Flux_Batch_2019-02.zip / Wonky Flux Batch 2019-02 / 023 - Big U Macroworks.dsk / BEEPERWORKS.bas < prev    next >
BASIC Source File  |  2019-02-16  |  8KB  |  123 lines
  1. 1 ID =  PEEK(49048): FOR I = 7 TO 2  STEP  -1: IF ID > = 2 ^I  THEN ID = ID -2 ^I
  2. 2  NEXT : IF ID <2  THEN  PRINT  CHR$(7)"THIS PROGRAM REQUIRES 80 COLUMNS.": END 
  3. 3  ONERR  GOTO 9000
  4. 5 D$ =  CHR$(4):Q$ =  CHR$(34):X = 20:P = 160:KP = 49152:KR = 49168:CL =  -868
  5. 8  FOR I = 1 TO 6: READ ME$(I): NEXT : FOR I = 1 TO 5: READ M2$(I): NEXT 
  6. 10  TEXT : HOME : PRINT D$"PR#3": PRINT 
  7. 14  VTAB 8: PRINT 
  8. 15  PRINT  SPC( X);" _______________________________________"
  9. 22  PRINT  SPC( X);"|                         TM            |"
  10. 24  PRINT  SPC( X);"|              BeeperWorks              |"
  11. 25  PRINT  SPC( X);"|                                       |"
  12. 28  PRINT  SPC( X);"|           Software Modifier           |"
  13. 40  PRINT  SPC( X);"|_______________________________________|"
  14. 45  VTAB 20: PRINT  SPC( 20)"By Randy Brandt and Beagle Bros, Inc."
  15. 50  PRINT  SPC( 20)"Copyright Beagle Bros, Inc. 1985 V1.1"
  16. 51  PRINT : PRINT "--------------------------------------------------------------------------------";
  17. 53  PRINT "Place the AppleWorks STARTUP disk in Drive 1 and press Return     ExtraK Avail.";
  18. 55 P = 192 -P: POKE 2031,P: FOR I = 0 TO (192 -P)/2:X =  PEEK(KP): IF X < >141  AND X < >155  THEN  NEXT : GOTO 55
  19. 57  POKE KR,0: POKE 2031,160: IF X = 155  THEN  HOME : PRINT "TYPE "Q$"RUN"Q$" TO RESTART.": END 
  20. 60  PRINT D$"BLOAD APLWORKS.SYSTEM,TSYS,A$2000"
  21. 61 BEEP = 9797: IF  PEEK(BEEP) < >160  OR  PEEK(BEEP +2) < >169  THEN BEEP = 9789
  22. 62  IF  PEEK(BEEP) < >160  OR  PEEK(BEEP +2) < >169  THEN 12000
  23. 63 DA = BEEP +1: REM  TONE DURATION ADDRESS
  24. 65 FA = BEEP +3: REM  TONE FREQUENCY ADDRESS
  25. 67 PA = 2 + PEEK(BEEP +20) +( PEEK(BEEP +21) +16) *256: REM  PAUSE ADDRESS
  26. 69 OD =  PEEK(DA):OF =  PEEK(FA):OP =  PEEK(PA): REM  ORIGINiL BOOT VALUES
  27. 105  REM <CTRL-J><CTRL-J><CTRL-J>
  28. 110  HOME : PRINT "Disk: Drive 1                       MAIN MENU"
  29. 112  POKE BEEP +21,47: POKE BEEP +22,96: REM  TEST PATCH
  30. 115  PRINT "________________________________________________________________________________";
  31. 120  PRINT "    __________________________"
  32. 125  PRINT "   |     Main Menu            |_____________________________________"
  33. 130  FOR I = 0 TO 13: POKE 1403,3: PRINT "|";: POKE 1403,68: PRINT "|": NEXT 
  34. 135  PRINT "   |________________________________________________________________|"
  35. 140  VTAB 6: FOR I = 1 TO 6: PRINT : POKE 1403,8: PRINT ME$(I): NEXT 
  36. 145 N = 1
  37. 150  VTAB 5 +(2 *N): POKE 1403,8: INVERSE : PRINT ME$(N)
  38. 155  NORMAL 
  39. 160  VTAB 23
  40. 165  PRINT "________________________________________________________________________________";
  41. 170  PRINT "Type number, or use arrows, then press Return               See Manual for Help";
  42. 175  REM <CTRL-J><CTRL-J><CTRL-J>
  43. 240 OC = 1:CC = 1: REM  OC=OLD CURSOR  CC=CURRENT CURSOR
  44. 500  GOSUB 8000: IF KEY = 0  THEN 500
  45. 502  IF KEY = 13  THEN  ON CC GOTO 1000,2000,3000,4000,5000,6000
  46. 505  IF KEY = 27  THEN 500
  47. 510 OC = CC: IF KEY >48  THEN CC = KEY -48: IF CC >100  THEN  STOP 
  48. 540  IF KEY = 10  THEN CC = CC +1: IF CC >6  THEN CC = 1
  49. 550  IF KEY = 11  THEN CC = CC -1: IF CC <1  THEN CC = 6
  50. 600  VTAB 5 +(2 *OC): POKE 1403,8: NORMAL : PRINT ME$(OC)
  51. 610  VTAB 5 +(2 *CC): POKE 1403,8: INVERSE : PRINT ME$(CC): NORMAL 
  52. 620  GOTO 500
  53. 1000  CALL BEEP: GOTO 500
  54. 2000  REM  
  55. 2003  VTAB 1: PRINT "Disk: Drive 1                    BEEP CHANGE MENU            Escape: Main Menu"
  56. 2005  VTAB 5
  57. 2112  POKE 1403,5: PRINT "  __________________________"
  58. 2113  POKE 1403,5: PRINT " |     Beep Change Menu     |_____________________________________"
  59. 2114  FOR I = 0 TO 13: POKE 1403,6: PRINT "|";: CALL CL: POKE 1403,71: PRINT "|": NEXT : VTAB 8
  60. 2115  POKE 1403,5: PRINT " |                             Current   Boot-up   AppleWorks     |"
  61. 2116  PRINT 
  62. 2117  POKE 1403,5: PRINT " |     1.  Change Pitch                               149         |"
  63. 2118  PRINT 
  64. 2119  POKE 1403,5: PRINT " |     2.  Change Duration                            149         |"
  65. 2120  PRINT 
  66. 2121  POKE 1403,5: PRINT " |     3.  Change Pause                               100         |"
  67. 2122  PRINT 
  68. 2123  POKE 1403,11: PRINT M2$(4): PRINT : POKE 1403,11: PRINT M2$(5): PRINT 
  69. 2149  PRINT 
  70. 2150  POKE 1403,3: PRINT "   |________________________________________________________________|"
  71. 2180 CD =  PEEK(DA):CF =  PEEK(FA):CP =  PEEK(PA): REM  CURRENT VALUES
  72. 2190 C2 = 1
  73. 2200  VTAB 10: POKE 1403,38: PRINT  RIGHT$("  " + STR$(CF),3);: POKE 1403,48: PRINT  RIGHT$("  " + STR$(OF),3)
  74. 2220  PRINT : POKE 1403,38: PRINT  RIGHT$("  " + STR$(CD),3);: POKE 1403,48: PRINT  RIGHT$("  " + STR$(OD),3)
  75. 2230  PRINT : POKE 1403,38: PRINT  RIGHT$("  " + STR$(CP),3);: POKE 1403,48: PRINT  RIGHT$("  " + STR$(OP),3)
  76. 2240  VTAB 8 +(2 *C2): POKE 1403,11: INVERSE : PRINT M2$(C2): NORMAL 
  77. 2500  GOSUB 8000: IF KEY = 27  OR C2 = 5  AND KEY = 13  THEN 110
  78. 2505  IF KEY = 54  THEN  CALL BEEP:KEY = 0
  79. 2506  IF KEY = 0  THEN 2500
  80. 2510  IF KEY = 13  THEN  ON C2 GOTO 2600,2700,2800,2900
  81. 2515 O2 = C2: IF KEY >48  THEN C2 = KEY -48
  82. 2540  IF KEY = 10  THEN C2 = C2 +1: IF C2 >5  THEN C2 = 1
  83. 2550  IF KEY = 11  THEN C2 = C2 -1: IF C2 <1  THEN C2 = 5
  84. 2560  VTAB 8 +(2 *O2): POKE 1403,11: NORMAL : PRINT M2$(O2)
  85. 2570  VTAB 8 +(2 *C2): POKE 1403,11: INVERSE : PRINT M2$(C2): NORMAL 
  86. 2575  GOTO 2500
  87. 2600  GOSUB 2950:CF = X: POKE FA,X: GOTO 2200
  88. 2700  GOSUB 2950:CD = X: POKE DA,X: GOTO 2200
  89. 2800  GOSUB 2950:CP = X: POKE PA,X: GOTO 2200
  90. 2900  CALL BEEP: GOTO 2500
  91. 2950  POKE 34,23
  92. 2955  VTAB 23: PRINT : PRINT "Enter new value (0 - 255) :";: CALL CL: INPUT " ";X$:X =  VAL(X$): IF X <0  OR X >255  THEN  CALL BEEP: GOTO 2955
  93. 2957  POKE 34,0
  94. 2960  PRINT "Type number, or use arrows, then press Return               See Manual for Help";: RETURN 
  95. 3000  POKE BEEP +21,31: POKE BEEP +22,76
  96. 3010  PRINT D$"UNLOCK APLWORKS.SYSTEM": PRINT D$"BSAVE APLWORKS.SYSTEM,TSYS,A$2000": GOTO 110
  97. 4000  POKE DA,149: POKE FA,149: POKE PA,100:OC = CC:CC = 1: GOTO 600
  98. 5000  POKE DA,OD: POKE FA,OF: POKE PA,OP:OC = CC:CC = 1: GOTO 600
  99. 6000  VTAB 23: PRINT : PRINT "Do you really want to do this? ";: INVERSE : PRINT " No ";: NORMAL : PRINT " Yes ";: CALL CL
  100. 6010  GOSUB 8100: IF KEY = 27  OR KEY = 13  THEN 6150
  101. 6020  IF KEY < >21  THEN  CALL BEEP: GOTO 6010
  102. 6030  VTAB 23: PRINT : PRINT "Do you really want to do this?  No ";: INVERSE : PRINT " Yes ";: NORMAL 
  103. 6035  GOSUB 8100: IF KEY = 27  THEN 6150
  104. 6037  IF KEY = 13  OR KEY = 89  OR KEY = 121  THEN  TEXT : HOME : END 
  105. 6045  IF KEY < >8  THEN  CALL BEEP: GOTO 6035
  106. 6050  GOTO 6000
  107. 6150  REM 
  108. 6175  VTAB 23: PRINT 
  109. 6180  PRINT "Type number, or use arrows, then press Return               See Manual for Help";
  110. 6190  GOTO 500
  111. 8000  WAIT KP,128:KEY =  PEEK(KP): POKE KR,0: IF KEY >128  THEN KEY = KEY -128
  112. 8002  IF KEY >54  OR (KEY <49  AND (KEY < >13  AND KEY < >10  AND KEY < >11  AND KEY < >27))  THEN  CALL BEEP:KEY = 0
  113. 8003  RETURN 
  114. 8100  WAIT KP,128:KEY =  PEEK(KP): POKE KR,0: IF KEY >128  THEN KEY = KEY -128
  115. 8110  IF KEY < >13  AND KEY < >21  AND KEY < >8  AND KEY < >27  THEN KEY = 0
  116. 8120  RETURN 
  117. 9000 ER =  PEEK(222):EL =  PEEK(219) *256 + PEEK(218)
  118. 9010  IF EL = 60  THEN  VTAB 23: PRINT  CHR$(7): PRINT "That was not the AppleWorks STARTUP disk; please insert it now";: GOTO 55
  119. 9015  IF EL = 3010  THEN  VTAB 23: PRINT : PRINT "Place the AppleWorks STARTUP disk in Drive 1 and press Return     ExtraK Avail.";: POKE 1403,63: GET X$: ON X$ =  CHR$(27) GOTO 500: GOTO 3010
  120. 9020  POKE 216,0: RESUME 
  121. 10000  DATA      " 1.  Listen to current beep "," 2.  Change the beep        "," 3.  Save current beep to disk "," 4.  Restore original AppleWorks beep "," 5.  Restore boot-up beep "," 6.  Quit "
  122. 10100  DATA  " 1.  Change Pitch "," 2.  Change Duration "," 3.  Change Pause "," 4.  Test current beep "," 5.  Return to Main Menu "
  123. 12000  VTAB 23: PRINT  CHR$(7): CALL CL: PRINT "Version 1.1, 1.2 or 1.3 of AppleWorks required."